Adding a texture to a fresnel shader

I’m working on adding a fresnel effect shader and I found a fantastic script here, but I’d like to add the ability to plug in a texture to the shader as well. I’m very new to C# and shader scripting, and from what I’ve been able to piece together by looking at other people’s code, I haven’t quite figured this out yet.

Currently, it has the option to plug in a map, but as you can see from the attached image, that texture doesn’t show up. Something is either overwriting it or it isn’t properly plugged in, but I’m not sure what.

Any ideas?

Shader "Custom/FresnelEffect"
{
	Properties
	{
		_InnerColor("Inner Color", Color) = (1.0, 1.0, 1.0, 1.0)
		_MainTex("Particle Texture", 2D) = "white" {}
		_RimColor("Rim Color", Color) = (0.26,0.19,0.16,0.0)
		_RimPower("Rim Power", Range(0.5,8.0)) = 3.0
	}
		SubShader
	{
		Tags{ "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }

		Cull Back
		Blend One One
		Lighting Off
		ZWrite Off

		CGPROGRAM
#pragma surface surf Lambert

	struct Input
	{
		float3 viewDir;
	};

	float4 _MainTex_ST;
	float4 _InnerColor;
	float4 _RimColor;
	float _RimPower;

	void surf(Input IN, inout SurfaceOutput o)
	{
		o.Albedo = _InnerColor.rgb;
		half rim = 1.0 - saturate(dot(normalize(IN.viewDir), o.Normal));
		o.Emission = _RimColor.rgb * pow(rim, _RimPower);
	}
	ENDCG
	}
		Fallback "Diffuse"
}

I figured it out!

Shader "Custom/TransparentFresnel"
{
	Properties
	{
		_MainTex("Texture", 2D) = "white" {}
		_InnerColor("Inner Color", Color) = (1.0, 1.0, 1.0, 1.0)
		_RimColor("Rim Color", Color) = (0.26,0.19,0.16,0.0)
		_RimPower("Rim Power", Range(0.5,8.0)) = 3.0
	}
		SubShader
	{
		Tags{ "Queue" = "Transparent" }

		Cull Back
		Blend One One
		ZWrite Off

		CGPROGRAM
#pragma surface surf Lambert

	struct Input
	{
		float2 uv_MainTex;
		float3 viewDir;
	};

	sampler2D _MainTex;
	float4 _InnerColor;
	float4 _RimColor;
	float _RimPower;

	void surf(Input IN, inout SurfaceOutput o)
	{
		o.Albedo = tex2D(_MainTex, IN.uv_MainTex).rgba * _InnerColor;
		half rim = 1.0 - saturate(dot(normalize(IN.viewDir), o.Normal));
		o.Emission = _RimColor.rgba * pow(rim, _RimPower);
	}
	ENDCG
	}
		Fallback "Diffuse"
}