How to Get Nice Thick Toon-Like Outlines On Non-Smooth Geometry?

This is a custom shader I wrote a while back that I generally use instead for this reason;

 Shader "Custom/CustomOutline" {
     Properties {
         _Color ("Color", Color) = (1,1,1,1)
         _Outline ("Outline Color", Color) = (0,0,0,1)
         _MainTex ("Albedo (RGB)", 2D) = "white" {}
         _Glossiness ("Smoothness", Range(0,1)) = 0.5
         _Metallic ("Metallic", Range(0,1)) = 0.0
         _Size ("Outline Thickness", Float) = 1.5
     }
     SubShader {
         Tags { "RenderType"="Opaque" }
         LOD 200
         
         Pass {
             Cull Front
 
             CGPROGRAM
             #pragma vertex vert
             #pragma fragment frag
 
             #include "UnityCG.cginc"
 
             half _Size;
 
             fixed4 _Outline;
 
             struct v2f {
                 float4 pos : SV_POSITION;
             };
 
             v2f vert (appdata_base v) {
                 v2f o;
                 v.vertex.xyz *= _Size;
                 v.normal *= -1;
                 o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
                 return o;
             }
 
             half4 frag (v2f i) : SV_Target
             {
                 return _Outline;
             }
             ENDCG
         }
 
         Cull Back
 
         CGPROGRAM
         // Physically based Standard lighting model, and enable shadows on all light types
         #pragma surface surf Standard fullforwardshadows
 
         // Use shader model 3.0 target, to get nicer looking lighting
         #pragma target 3.0
 
         sampler2D _MainTex;
 
         struct Input {
             float2 uv_MainTex;
         };
 
         half _Glossiness;
         half _Metallic;
         fixed4 _Color;
 
         void surf (Input IN, inout SurfaceOutputStandard o) {
             // Albedo comes from a texture tinted by color
             fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
             o.Albedo = c.rgb;
             // Metallic and smoothness come from slider variables
             o.Metallic = _Metallic;
             o.Smoothness = _Glossiness;
             o.Alpha = c.a;
         }
         ENDCG
     }
     FallBack "Diffuse"
 }

Rather than extrude along the normal, I figured it was a better idea to extrude based upon the vector from the origin towards the vertex position. An easy way of doing this is to simply multiply the local vertex position.